Cari Tahu Sisa Tempat Parkir dari Handphone

Cari Tahu Sisa Tempat Parkir dari Handphone

Ketika berpergian terutama diarea perkotaan terkadang kita akan sulit mencari tempat parkir, untuk itu kita perlu inovasi yang dapat mempermudah dalam mengetahui sisa tempat parkir yang ada dan dapat digunakan melalui smartphone kita.

1. Alat / Bahan

Arduino IDE Download disini
Library: Blynk Download disini
Library: ESP8266 Download disini
Library: LiquidCrystal_I2C Download disini
NodeMCU ESP8266 1 Buah
Sensor IR Obstacle 2 Buah
LCD 16×2 1 Buah
I2C 1 Buah
Project Board 1 Buah
Kabel Jumper Secukupnya
Smartphone 1 Buah

Untuk mendapatkan komponen elektronik di atas silahkan temukan disini.

2. Skema Rangkaian

Gambar Rangkaian Cari Tahu Sisa Tempat Parkir dari Handphone

Keterangan:

VU – VCC IR, VCC IR, VCC I2C
GND – GND IR, GND IR, GND I2C
D1 – SCL I2C
D2 – SDA I2CL
D3 – Pin Data IR1
D4 – Pin Data IR2
Pin LCD – Pin I2C

3. Layout Blynk

Keterangan:

Sisa Tempat Parkir (Value Display)
- Input V0, Low = 0, High = 400

4. Langkah Kerja

Siapkan alat dan bahan yang akan digunakan
Lakukan proses wiring dengan menggunakan Gambar skematik rangkaian diatas
Buka software Arduino IDE yang telah terinstal pada laptop/komputer
Unduh semua library di atas dan masukkan libray tersebut dengan cara buka Arduino IDE pilih Sketch->Include Library->Add.Zip Library
Ketikkan sketch program pada halaman Arduino IDE
Sesuaikan Auth Tokens dengan proyek aplikasi Blynk. Cara setting dan mendapatkan Auth Tokens dapat dilihat pada tutorial berikut:
Setting Blynk untuk NodeMCU ESP8266
Ganti ssid dan pass dengan nama wifi dan password wifi yang kalian gunakan
Lakukan proses uploading program
Buka aplikasi Blynk
Buat layout Blynk seperti gambar di atas.
Tekan tombol Play pada aplikasi Blynk lalu tunggu hingga proyek kalian terhubung dengan aplikasi Blynk

5. Sketch Program

/* Program Cari Tahu Sisa Tempat Parkir dari Handphone dibuat oleh Guru Mudiak */
 
#include <ESP8266WiFi.h>              //Library ESP8266
#include <BlynkSimpleEsp8266.h>       //Library Blynk
 
char auth[] = "HoP9z23_PbWp-iEyMBYFGnnALYBvvcXS"; //Token
char ssid[] = "Wifi.id";                          //Nama wifi
char pass[] = "alam oye";                         //Password wifi
 
BlynkTimer timer;
 
#include <LiquidCrystal_I2C.h>      //Library LCD I2C
LiquidCrystal_I2C lcd(0x27,16,2);   //Alamat I2C
 
#define Sensor_Masuk 0    //Inisialisasi sensor IR di pin D3
#define Sensor_Keluar 2   //Inisialisasi sensor IR di pin D4
 
int Kondisi_Masuk;                //Variabel penampung data sensor
int Kondisi_Keluar;
bool Kendaraan_Masuk = false;     //Variabel logika sensor
bool Kendaraan_Keluar = false;
int Jumlah_Ruang = 400;           //Jumlah sisa tempat parkir
 
void setup() {
  Blynk.begin(auth, ssid, pass);          //Inisialisasi token, wifi dan password
  timer.setInterval(1000L, sendSensor);   //Kirim data sensor
  lcd.init ();                    //Nyalakan LCD
  lcd.setBacklight(HIGH);         //Nyalakan backlight
  pinMode(Sensor_Masuk, INPUT);   //Setting sensor sebagai input
  pinMode(Sensor_Keluar, INPUT);
}
 
void loop() {
  Blynk.run();                        //Jalankan pembacaan Blynk
  timer.run();
 
  Kondisi_Masuk = digitalRead(Sensor_Masuk);    //Baca sensor
  Kondisi_Keluar = digitalRead(Sensor_Keluar);
 
  if(Kondisi_Masuk == LOW && Kendaraan_Masuk){        //Jika ada kendaraan masuk, maka
    Jumlah_Ruang -= 1;                                //Kurangi sisa ruang parkir
    Kendaraan_Masuk = false;
  }
  else if(Kondisi_Masuk == HIGH && !Kendaraan_Masuk){
    Kendaraan_Masuk = true;
  }
 
  if(Kondisi_Keluar == LOW && Kendaraan_Keluar){      //Jika ada kendaraan keluar, maka
    Jumlah_Ruang += 1;                                //Tambah sisa ruang parkir
    Kendaraan_Keluar = false;
  }
  else if(Kondisi_Keluar == HIGH && !Kendaraan_Keluar){
    Kendaraan_Keluar = true;
  }
 
  lcd.setCursor(0,0);
  lcd.print("Ruang Parkir");
  lcd.setCursor(0,1);
  lcd.print(Jumlah_Ruang);        //Tampilkan sisa ruang parkir pada LCD
  delay(200);
  lcd.clear();
}
 
void sendSensor(){                  //Kirim data sensor
  Blynk.virtualWrite(V0,Jumlah_Ruang);
}

Kesimpulan:

Ketika kita mencari tempat parkir manggunakan handphone kita dapat mengetahui sisa parkir pada suatu gedung yang kita tuju dan juga kita dapat mengetahui sisa parkir dengan melihat pada layar LCD ketika berada dipintu masuk tempat parkir.